Arduino Nesso N1 LoRa 通信

Arduino Nesso N1 の LoRa 通信に関する API およびサンプルプログラム。

注意

Arduino Nesso N1 は SX1262 LoRa 通信用チップを使用しており、開発時には対応するクラスを選択してください。

サンプルプログラム

コンパイル要件

M5Stack ボードマネージャバージョン >= 3.2.5
ボードオプション = ArduinoNessoN1
M5GFX ライブラリバージョン >= 0.2.17
M5Unified ライブラリバージョン >= 0.2.11
RadioLib ライブラリバージョン >= 7.3.0

送信側

cpp 
#include "M5Unified.h"
#include <RadioLib.h>

#define LORA_MOSI_PIN 21
#define LORA_MISO_PIN 22
#define LORA_SCK_PIN 20
#define LORA_IRQ_PIN 15
#define LORA_CS_PIN 23
#define LORA_BUSY_PIN 19

// SX1262: NSS, DIO1, NRST, BUSY
SX1262 radio = new Module(LORA_CS_PIN, LORA_IRQ_PIN, RADIOLIB_NC, LORA_BUSY_PIN);

// 送信状態を保持
int transmissionState = RADIOLIB_ERR_NONE;

// パケット送信完了のフラグ
volatile bool transmittedFlag = false;

// モジュールによるパケット送信完了時に呼ばれる関数
#if defined(ESP8266) || defined(ESP32)
ICACHE_RAM_ATTR
#endif
void setFlag(void) {
  // 送信完了フラグを設定
  transmittedFlag = true;
}

M5Canvas canvas(&M5.Display);

void setup() {
  M5.begin();
  Serial.begin(115200);
  M5.Display.setRotation(1);

  // LED_BUILTIN at E1.P7
  auto& ioe = M5.getIOExpander(0);

  //LORA_RESET
  ioe.digitalWrite(7, false);
  delay(100);
  ioe.digitalWrite(7, true);
  delay(100);

  ioe.digitalWrite(5, true);  //LORA_LNA_ENABLE
  ioe.digitalWrite(6, true);  //LORA_ANTENNA_SWITCH

  canvas.createSprite(M5.Display.width(), M5.Display.height());
  canvas.setTextColor(GREEN);
  canvas.setTextScroll(true);
  // SX1262 初期化
  Serial.print(F("[SX1262] Initializing ... "));
  canvas.println("[SX1262] Initializing ... ");
  canvas.pushSprite(0, 0);

  // 周波数、帯域幅、拡散率、符号化率、同期ワード、送信パワー、前置長、TCXO基準電圧、useRegulatorLDO
  int state = radio.begin(868.0, 125.0f, 12, 5, 0x34, 22, 20, 3.0, true);
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) {
      delay(10);
    }
  }

  // パケット送信完了時のコールバックを設定
  radio.setPacketSentAction(setFlag);

  // 最初のパケット送信を開始
  Serial.print(F("[SX1262] Sending first packet ... "));

  // 最大256文字の文字列を送信可能
  transmissionState = radio.startTransmit("Hello world from M5Stack!");
}

// 送信パケットカウント
int count = 0;

void loop() {
  // 前回の送信が完了したか確認
  if (transmittedFlag) {
    // フラグリセット
    transmittedFlag = false;

    if (transmissionState == RADIOLIB_ERR_NONE) {
      Serial.println(F("transmission finished!"));
      canvas.println("OK!");
      canvas.pushSprite(0, 0);
    } else {
      Serial.print(F("failed, code "));
      Serial.println(transmissionState);
    }

    // 送信完了後の後処理を実行
    radio.finishTransmit();

    // 再送信まで 1 秒待機
    delay(1000);

    // 新しいパケットを送信
    Serial.print(F("[SX1262] Sending another packet ... "));
    String str = "Hello Arduino Nesso N1 #" + String(count++);
    transmissionState = radio.startTransmit(str);
    canvas.println("Send:" + str);
    canvas.pushSprite(0, 0);
  }
  delay(100);
}

受信側

cpp 
#include "M5Unified.h"
#include <RadioLib.h>

#define LORA_MOSI_PIN 21
#define LORA_MISO_PIN 22
#define LORA_SCK_PIN 20
#define LORA_IRQ_PIN 15
#define LORA_CS_PIN 23
#define LORA_BUSY_PIN 19

// SX1262: NSS, DIO1, NRST, BUSY
SX1262 radio = new Module(LORA_CS_PIN, LORA_IRQ_PIN, RADIOLIB_NC, LORA_BUSY_PIN);

// パケット受信フラグ
volatile bool receivedFlag = false;

// モジュールによるパケット受信時に呼ばれる関数
#if defined(ESP8266) || defined(ESP32)
ICACHE_RAM_ATTR
#endif
void setFlag(void) {
  receivedFlag = true;
}

M5Canvas canvas(&M5.Display);

void setup() {
  M5.begin();
  Serial.begin(115200);
  M5.Display.setRotation(1);

  auto& ioe = M5.getIOExpander(0);

  //LORA_RESET
  ioe.digitalWrite(7, false);
  delay(100);
  ioe.digitalWrite(7, true);
  delay(100);

  ioe.digitalWrite(5, true);  //LORA_LNA_ENABLE
  ioe.digitalWrite(6, true);  //LORA_ANTENNA_SWITCH

  canvas.createSprite(M5.Display.width(), M5.Display.height());
  canvas.setTextColor(GREEN);
  canvas.setTextScroll(true);
  Serial.print(F("[SX1262] Initializing ... "));
  canvas.println("[SX1262] Initializing ... ");
  canvas.pushSprite(0, 0);

  int state = radio.begin(868.0, 125.0f, 12, 5, 0x34, 22, 20, 3.0, true);
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) { delay(10); }
  }

  radio.setPacketReceivedAction(setFlag);

  Serial.print(F("[SX1262] Starting to listen ... "));
  state = radio.startReceive();
  if (state == RADIOLIB_ERR_NONE) {
    Serial.println(F("success!"));
  } else {
    Serial.print(F("failed, code "));
    Serial.println(state);
    while (true) { delay(10); }
  }
}

void loop() {
  if (receivedFlag) {
    receivedFlag = false;

    String str;
    int state = radio.readData(str);

    if (state == RADIOLIB_ERR_NONE) {
      Serial.println(F("[SX1262] Received packet!"));
      Serial.print(F("[SX1262] Data:\t\t"));
      Serial.println(str);

      canvas.print(F("[SX1262] Data:\t\t"));
      canvas.println(str);

      Serial.print(F("[SX1262] RSSI:\t\t"));
      Serial.print(radio.getRSSI());
      Serial.println(F(" dBm"));

      canvas.print(F("[SX1262] RSSI:\t\t"));
      canvas.print(radio.getRSSI());
      canvas.println(F(" dBm"));

      Serial.print(F("[SX1262] SNR:\t\t"));
      Serial.print(radio.getSNR());
      Serial.println(F(" dB"));

      canvas.print(F("[SX1262] SNR:\t\t"));
      canvas.print(radio.getSNR());
      canvas.println(F(" dB"));
      canvas.pushSprite(0, 0);

      Serial.print(F("[SX1262] Frequency error:\t"));
      Serial.print(radio.getFrequencyError());
      Serial.println(F(" Hz"));

    } else if (state == RADIOLIB_ERR_CRC_MISMATCH) {
      Serial.println(F("CRC error!"));
    } else {
      Serial.print(F("failed, code "));
      Serial.println(state);
    }
  }
}

実行結果

2 つのコードをそれぞれ 2 台の Arduino Nesso N1 にコンパイルしてアップロードします。送信側と受信側で、それぞれ送信状態と受信状態が表示されます。

API

Arduino Nesso N1 の LoRa 通信部分は RadioLib ライブラリを使用しています。詳細な API については、以下のドキュメントを参照してください。

Next 1. Arduino環境設定 - 1. Arduino IDEインストール

1. Arduino環境設定

2. デバイス＆サンプル

Tab5

Arduino Nesso N1

Atom EchoS3R

Atom-Lite / Atom-Matrix

AtomS3 / AtomS3-Lite

AtomS3U

Basic/Gray

Capsule

Cardputer / -Adv

Chain DualKey

Core2/Core2 For AWS

CoreInk

CoreS3

Dial

DinMeter