CoreMatrix microSD 卡

#include <Arduino.h>
#include <SPI.h>
#include <SD.h>
#include <M5Unified.h>
#include <utility/M5IOE1_Class.hpp>

static constexpr uint8_t SD_CS_PIN = 28;
static constexpr uint8_t SD_SCK_PIN = 25;
static constexpr uint8_t SD_MISO_PIN = 26;
static constexpr uint8_t SD_MOSI_PIN = 27;

static constexpr auto TF_DET = m5::M5IOE1_Class::gpio10;

static void drawResult(bool ok)
{
  M5.Display.startWrite();
  M5.Display.fillScreen(TFT_BLACK);
  M5.Display.drawRect(0, 0, 16, 16, TFT_WHITE);

  if (ok) {
    M5.Display.drawLine(2, 7, 6, 11, TFT_WHITE);
    M5.Display.drawLine(7, 10, 13, 4, TFT_WHITE);
  } else {
    M5.Display.drawLine(3, 3, 12, 12, TFT_WHITE);
    M5.Display.drawLine(12, 3, 3, 12, TFT_WHITE);
  }

  M5.Display.endWrite();
  M5.Display.display();
}

static bool prepareTfCard()
{
  auto& ioe = M5.getIOExpander(0);

  // Card detect is active low: M5IOE1 IO10 -> PYB_TFCARD_DET
  ioe.setDirection(TF_DET, false);
  ioe.setPullMode(TF_DET, m5::IOExpander_Base::pull_up);
  delay(50);

  bool level = true;
  if (!ioe.getInputLevel(TF_DET, &level)) {
    Serial.println("TF card detect read failed");
    return false;
  }

  Serial.printf("TF card detect level: %s\n", level ? "HIGH" : "LOW");
  return !level;
}

void setup()
{
  auto cfg = M5.config();
  cfg.serial_baudrate = 115200;
  M5.begin(cfg);

  M5.Display.setColorDepth(8);
  M5.Display.setRotation(1);
  M5.Display.setBrightness(128);

  if (!prepareTfCard()) {
    Serial.println("TF card not inserted");
    drawResult(false);
    return;
  }

  SPI.begin(SD_SCK_PIN, SD_MISO_PIN, SD_MOSI_PIN, SD_CS_PIN);
  if (!SD.begin(SD_CS_PIN, SPI, 25000000)) {
    Serial.println("SD mount failed");
    drawResult(false);
    return;
  }

  File file = SD.open("/corematrix.txt", FILE_WRITE);
  if (!file) {
    Serial.println("File open for write failed");
    drawResult(false);
    return;
  }

  file.println("Hello CoreMatrix");
  file.close();

  file = SD.open("/corematrix.txt", FILE_READ);
  if (!file) {
    Serial.println("File open for read failed");
    drawResult(false);
    return;
  }

  const String line = file.readStringUntil('\n');
  file.close();

  Serial.printf("Read back: %s\n", line.c_str());
  drawResult(true);
}

void loop()
{
  delay(1000);
}